pywidx.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file pywidx.f

 
C***********************************************************************
 
C...PYWIDX
C...Calculates full and partial widths of resonances.
C....copy of PYWIDT, used for techniparticle widths
 
      SUBROUTINE pywidx(KFLR,SH,WDTP,WDTE)
 
C...Double precision and integer declarations.
      IMPLICIT DOUBLE PRECISION(a-h, o-z)
      IMPLICIT INTEGER(i-n)
      INTEGER pyk,pychge,pycomp
C...Parameter statement to help give large particle numbers.
      parameter(ksusy1=1000000,ksusy2=2000000,ktechn=3000000,
     &kexcit=4000000,kdimen=5000000)
C...Commonblocks.
      common/pydat1/mstu(200),paru(200),mstj(200),parj(200)
      common/pydat2/kchg(500,4),pmas(500,4),parf(2000),vckm(4,4)
      common/pydat3/mdcy(500,3),mdme(8000,2),brat(8000),kfdp(8000,5)
      common/pysubs/msel,mselpd,msub(500),kfin(2,-40:40),ckin(200)
      common/pypars/mstp(200),parp(200),msti(200),pari(200)
      common/pyint1/mint(400),vint(400)
      common/pyint4/mwid(500),wids(500,5)
      common/pymssm/imss(0:99),rmss(0:99)
      common/pytcsm/itcm(0:99),rtcm(0:99)
      SAVE /pydat1/,/pydat2/,/pydat3/,/pysubs/,/pypars/,/pyint1/,
     &/pyint4/,/pymssm/,/pytcsm/
C...Local arrays and saved variables.
      dimension wdtp(0:400),wdte(0:400,0:5),mofsv(3,2),widwsv(3,2),
     &wid2sv(3,2)
      SAVE mofsv,widwsv,wid2sv
      DATA mofsv/6*0/,widwsv/6*0d0/,wid2sv/6*0d0/
 
C...Compressed code and sign; mass.
      kfla=iabs(kflr)
      kfls=isign(1,kflr)
      kc=pycomp(kfla)
      shr=sqrt(sh)
      pmr=pmas(kc,1)
 
C...Reset width information.
      DO 110 i=0,200
        wdtp(i)=0d0
        DO 100 j=0,5
          wdte(i,j)=0d0
  100   CONTINUE
  110 CONTINUE
 
C...Common electroweak and strong constants.
      xw=paru(102)
      xwv=xw
      IF(mstp(8).GE.2) xw=1d0-(pmas(24,1)/pmas(23,1))**2
      xw1=1d0-xw
      aem=pyalem(sh)
      IF(mstp(8).GE.1) aem=sqrt(2d0)*paru(105)*pmas(24,1)**2*xw/paru(1)
      as=pyalps(sh)
      radc=1d0+as/paru(1)
 
      IF(kfla.EQ.23) THEN
C...Z0:
        icase=1
        xwc=1d0/(16d0*xw*xw1)
        fac=(aem*xwc/3d0)*shr
  120   CONTINUE
        DO 130 i=1,mdcy(kc,3)
          idc=i+mdcy(kc,2)-1
          IF(mdme(idc,1).LT.0) goto 130
          rm1=pmas(iabs(kfdp(idc,1)),1)**2/sh
          rm2=pmas(iabs(kfdp(idc,2)),1)**2/sh
          IF(sqrt(rm1)+sqrt(rm2).GT.1d0) goto 130
          wid2=1d0
          IF(i.LE.8) THEN
C...Z0 -> q + qbar
            ef=kchg(i,1)/3d0
            af=sign(1d0,ef+0.1d0)
            vf=af-4d0*ef*xwv
            fcof=3d0*radc
            IF(i.GE.6.AND.mstp(35).GE.1) fcof=fcof*pyhfth(sh,sh*rm1,1d0)
            IF(i.EQ.6) wid2=wids(6,1)
            IF((i.EQ.7.OR.i.EQ.8)) wid2=wids(i,1)
          ELSEIF(i.LE.16) THEN
C...Z0 -> l+ + l-, nu + nubar
            ef=kchg(i+2,1)/3d0
            af=sign(1d0,ef+0.1d0)
            vf=af-4d0*ef*xwv
            fcof=1d0
            IF((i.EQ.15.OR.i.EQ.16)) wid2=wids(2+i,1)
          ENDIF
          be34=sqrt(max(0d0,1d0-4d0*rm1))
            wdtp(i)=fac*fcof*(vf**2*(1d0+2d0*rm1)+af**2*(1d0-4d0*rm1))*
     &      be34
            wdtp(0)=wdtp(0)+wdtp(i)
          IF(mdme(idc,1).GT.0) THEN
              wdte(i,mdme(idc,1))=wdtp(i)*wid2
              wdte(0,mdme(idc,1))=wdte(0,mdme(idc,1))+
     &        wdte(i,mdme(idc,1))
              wdte(i,0)=wdte(i,mdme(idc,1))
              wdte(0,0)=wdte(0,0)+wdte(i,0)
          ENDIF
  130   CONTINUE
 
 
      ELSEIF(kfla.EQ.24) THEN
C...W+/-:
        fac=(aem/(24d0*xw))*shr
        DO 140 i=1,mdcy(kc,3)
          idc=i+mdcy(kc,2)-1
          IF(mdme(idc,1).LT.0) goto 140
          rm1=pmas(iabs(kfdp(idc,1)),1)**2/sh
          rm2=pmas(iabs(kfdp(idc,2)),1)**2/sh
          IF(sqrt(rm1)+sqrt(rm2).GT.1d0) goto 140
          wid2=1d0
          IF(i.LE.16) THEN
C...W+/- -> q + qbar'
            fcof=3d0*radc*vckm((i-1)/4+1,mod(i-1,4)+1)
            IF(kflr.GT.0) THEN
              IF(mod(i,4).EQ.3) wid2=wids(6,2)
              IF(mod(i,4).EQ.0) wid2=wids(8,2)
              IF(i.GE.13) wid2=wid2*wids(7,3)
            ELSE
              IF(mod(i,4).EQ.3) wid2=wids(6,3)
              IF(mod(i,4).EQ.0) wid2=wids(8,3)
              IF(i.GE.13) wid2=wid2*wids(7,2)
            ENDIF
          ELSEIF(i.LE.20) THEN
C...W+/- -> l+/- + nu
            fcof=1d0
            IF(kflr.GT.0) THEN
              IF(i.EQ.20) wid2=wids(17,3)*wids(18,2)
            ELSE
              IF(i.EQ.20) wid2=wids(17,2)*wids(18,3)
            ENDIF
          ENDIF
          wdtp(i)=fac*fcof*(2d0-rm1-rm2-(rm1-rm2)**2)*
     &    sqrt(max(0d0,(1d0-rm1-rm2)**2-4d0*rm1*rm2))
          wdtp(0)=wdtp(0)+wdtp(i)
          IF(mdme(idc,1).GT.0) THEN
            wdte(i,mdme(idc,1))=wdtp(i)*wid2
            wdte(0,mdme(idc,1))=wdte(0,mdme(idc,1))+wdte(i,mdme(idc,1))
            wdte(i,0)=wdte(i,mdme(idc,1))
            wdte(0,0)=wdte(0,0)+wdte(i,0)
          ENDIF
  140   CONTINUE
 
C.....V8 -> quark anti-quark
      ELSEIF(kfla.EQ.ktechn+100021) THEN
        fac=as/6d0*shr
        tant3=rtcm(21)
        IF(itcm(2).EQ.0) THEN
          imdl=1
        ELSEIF(itcm(2).EQ.1) THEN
          imdl=2
        ENDIF
        DO 150 i=1,mdcy(kc,3)
          idc=i+mdcy(kc,2)-1
          IF(mdme(idc,1).LT.0) goto 150
          pm1=pmas(pycomp(kfdp(idc,1)),1)
          rm1=pm1**2/sh
          IF(rm1.GT.0.25d0) goto 150
          wid2=1d0
          IF(i.EQ.5.OR.i.EQ.6.OR.imdl.EQ.2) THEN
            fmix=1d0/tant3**2
          ELSE
            fmix=tant3**2
          ENDIF
          wdtp(i)=fac*(1d0+2d0*rm1)*sqrt(1d0-4d0*rm1)*fmix
          IF(i.EQ.6) wid2=wids(6,1)
          wdtp(0)=wdtp(0)+wdtp(i)
          IF(mdme(idc,1).GT.0) THEN
            wdte(i,mdme(idc,1))=wdtp(i)*wid2
            wdte(0,mdme(idc,1))=wdte(0,mdme(idc,1))+wdte(i,mdme(idc,1))
            wdte(i,0)=wdte(i,mdme(idc,1))
            wdte(0,0)=wdte(0,0)+wdte(i,0)
          ENDIF
  150   CONTINUE
      ENDIF
 
      RETURN
      END