ulalps.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file ulalps.f

    
C*********************************************************************  
    
      FUNCTION ulalps(Q2)   
    
C...Purpose: to give the value of alpha_strong. 
      common/ludat1/mstu(200),paru(200),mstj(200),parj(200) 
      SAVE /ludat1/ 
      common/ludat2/kchg(500,3),pmas(500,4),parf(2000),vckm(4,4)    
      SAVE /ludat2/ 
    
C...Constant alpha_strong trivial.  
      IF(mstu(111).LE.0) THEN   
        ulalps=paru(111)    
        mstu(118)=mstu(112) 
        paru(117)=0.    
        paru(118)=paru(111) 
        RETURN  
      ENDIF 
    
C...Find effective Q2, number of flavours and Lambda.   
      q2eff=q2  
      IF(mstu(115).GE.2) q2eff=max(q2,paru(114))    
      nf=mstu(112)  
      alam2=paru(112)**2    
  100 IF(nf.GT.max(2,mstu(113))) THEN   
        q2thr=paru(113)*pmas(nf,1)**2   
        IF(q2eff.LT.q2thr) THEN 
          nf=nf-1   
          alam2=alam2*(q2thr/alam2)**(2./(33.-2.*nf))   
          goto 100  
        ENDIF   
      ENDIF 
  110 IF(nf.LT.min(8,mstu(114))) THEN   
        q2thr=paru(113)*pmas(nf+1,1)**2 
        IF(q2eff.GT.q2thr) THEN 
          nf=nf+1   
          alam2=alam2*(alam2/q2thr)**(2./(33.-2.*nf))   
          goto 110  
        ENDIF   
      ENDIF 
      IF(mstu(115).EQ.1) q2eff=q2eff+alam2  
      paru(117)=sqrt(alam2) 
    
C...Evaluate first or second order alpha_strong.    
      b0=(33.-2.*nf)/6. 
      algq=log(q2eff/alam2) 
      IF(mstu(111).EQ.1) THEN   
        ulalps=paru(2)/(b0*algq)    
      ELSE  
        b1=(153.-19.*nf)/6. 
        ulalps=paru(2)/(b0*algq)*(1.-b1*log(algq)/(b0**2*algq)) 
      ENDIF 
      mstu(118)=nf  
      paru(118)=ulalps  
    
      RETURN    
      END