pyhggm.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file pyhggm.f

 
C*********************************************************************
 
C...PYHGGM
C...Determines the Higgs boson mass spectrum using several inputs.
 
      SUBROUTINE pyhggm(ALPHA)
 
C...Double precision and integer declarations.
      IMPLICIT DOUBLE PRECISION(a-h, o-z)
      IMPLICIT INTEGER(i-n)
      INTEGER pyk,pychge,pycomp
C...Parameter statement to help give large particle numbers.
      parameter(ksusy1=1000000,ksusy2=2000000,ktechn=3000000,
     &kexcit=4000000,kdimen=5000000)
C...Commonblocks.
      common/pydat1/mstu(200),paru(200),mstj(200),parj(200)
      common/pydat2/kchg(500,4),pmas(500,4),parf(2000),vckm(4,4)
      common/pypars/mstp(200),parp(200),msti(200),pari(200)
      common/pymssm/imss(0:99),rmss(0:99)
      SAVE /pydat1/,/pydat2/,/pypars/,/pymssm/
 
C...Local variables.
      DOUBLE PRECISION at,ab,xmu,tanb
      DOUBLE PRECISION alpha
      INTEGER ihopt
      DOUBLE PRECISION dma,dtanb,dmq,dmur,dmtop,dau,dad
      DOUBLE PRECISION dmu,dmh,dhm,dmhch,dsa,dca,dtanba
      DOUBLE PRECISION dmc,dmdr,dmhp,dhmp,damp
      DOUBLE PRECISION dstop1,dstop2,dsbot1,dsbot2
 
      ihopt=imss(4)
      IF(ihopt.EQ.2) THEN
        alpha=rmss(18)
        RETURN
      ENDIF
      at=rmss(16)
      ab=rmss(15)
      dmgl=rmss(3)
      xmu=rmss(4)
      tanb=rmss(5)
 
      dma=rmss(19)
      dtanb=tanb
      dmq=rmss(10)
      dmur=rmss(12)
      dmdr=rmss(11)
      dmtop=pmas(6,1)
      dmc=pmas(pycomp(ksusy1+37),1)
      dau=at
      dad=ab
      dmu=xmu
      rmss(40)=0d0
      rmss(41)=0d0
 
      IF(ihopt.EQ.0) THEN
        CALL pysubh(dma,dtanb,dmq,dmur,dmtop,dau,dad,dmu,dmh,dhm,
     &  dmhch,dsa,dca,dtanba)
      ELSEIF(ihopt.EQ.1) THEN
        CALL pysubh(dma,dtanb,dmq,dmur,dmtop,dau,dad,dmu,dmh,dhm,
     &  dmhch,dsa,dca,dtanba)
        CALL pypole(3,dmc,dma,dtanb,dmq,dmur,dmdr,dmtop,dau,dad,dmu,
     &  dmh,dmhp,dhm,dhmp,damp,dsa,dca,
     &  dstop1,dstop2,dsbot1,dsbot2,dtanba,dmgl,ddt,ddb)
        rmss(40)=ddt
        rmss(41)=ddb
        dmh=dmhp
        dhm=dhmp
        dma=damp
        IF(abs(pmas(pycomp(1000006),1)-dstop2).GT.5d-1) THEN
         WRITE(mstu(11),*) ' STOP1 MASS DOES NOT MATCH IN PYHGGM '
         WRITE(mstu(11),*) ' STOP1 MASSES = ',
     & pmas(pycomp(1000006),1),dstop2
        ENDIF
        IF(abs(pmas(pycomp(2000006),1)-dstop1).GT.5d-1) THEN
         WRITE(mstu(11),*) ' STOP2 MASS DOES NOT MATCH IN PYHGGM '
         WRITE(mstu(11),*) ' STOP2 MASSES = ',
     & pmas(pycomp(2000006),1),dstop1
        ENDIF
        IF(abs(pmas(pycomp(1000005),1)-dsbot2).GT.5d-1) THEN
         WRITE(mstu(11),*) ' SBOT1 MASS DOES NOT MATCH IN PYHGGM '
         WRITE(mstu(11),*) ' SBOT1 MASSES = ',
     & pmas(pycomp(1000005),1),dsbot2
        ENDIF
        IF(abs(pmas(pycomp(2000005),1)-dsbot1).GT.5d-1) THEN
         WRITE(mstu(11),*) ' SBOT2 MASS DOES NOT MATCH IN PYHGGM '
         WRITE(mstu(11),*) ' SBOT2 MASSES = ',
     & pmas(pycomp(2000005),1),dsbot1
        ENDIF
 
      ELSEIF (ihopt.EQ.3) THEN
c...Use FeynHiggs to fix Higgs sector (cf feynhiggs.de)
C...Currently only available for SLHA spectrum read-in.
        IF (imss(1).NE.11.AND.imss(1).NE.12.AND.imss(1).NE.13) THEN
          CALL pyerrm(11,'(PYHGGM:) FeynHiggs needs SLHA or ISASUSY'
     &         //' spectrum, change IMSS(1) or IMSS(4) option.')
        ENDIF
        alpha=rmss(18)
        RETURN
      ENDIF
 
      alpha=acos(dca)
 
      pmas(25,1)=dmh
      pmas(35,1)=dhm
      pmas(36,1)=dma
      pmas(37,1)=dmhch
 
      RETURN
      END