pyfeyn.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file pyfeyn.f

 
C*********************************************************************
 
C...PYFEYN
C...Interface to FeynHiggs for MSSM Higgs sector.
C...Pythia6.402: Updated to FeynHiggs v.2.3.0+ w/ DOUBLE COMPLEX
C...P. Skands
 
      SUBROUTINE pyfeyn(IERR)
 
C...Double precision and integer declarations.
      IMPLICIT DOUBLE PRECISION(a-h, o-z)
      IMPLICIT INTEGER(i-n)
      INTEGER pyk,pychge,pycomp
C...Commonblocks.
      common/pydat1/mstu(200),paru(200),mstj(200),parj(200)
      common/pydat2/kchg(500,4),pmas(500,4),parf(2000),vckm(4,4)
C...SUSY blocks
      common/pymssm/imss(0:99),rmss(0:99)
C...FeynHiggs variables
      DOUBLE PRECISION rmhigg(4)
      DOUBLE COMPLEX saeff, uhiggs(3,3)
      DOUBLE COMPLEX dmu,
     &     ae33, au33, ad33, ae22, au22, ad22, ae11, au11, ad11,
     &     dm1, dm2, dm3
C...SLHA Common Block
      common/pylh3p/modsel(200),parmin(100),parext(200),rmsoft(0:100),
     &     au(3,3),ad(3,3),ae(3,3)
      SAVE /pydat1/,/pydat2/,/pymssm/,/pylh3p/
 
      ierr=0
      CALL fhsetflags(ierr,4,0,0,2,0,2,1,1)
      IF (ierr.NE.0) THEN
        CALL pyerrm(11,'(PYHGGM:) Caught error from FHSETFLAGS.'
     &       //'Will not use FeynHiggs for this run.')
        RETURN
      ENDIF
      q=rmsoft(0)
      dmb=pmas(5,1)
      dmt=pmas(6,1)
      dmz=pmas(23,1)
      dmw=pmas(24,1)
      dma=pmas(36,1)
      dm1=rmsoft(1)
      dm2=rmsoft(2)
      dm3=rmsoft(3)
      dtanb=rmss(5)
      dmu=rmss(4)
      dm3sl=rmsoft(33)
      dm3se=rmsoft(36)
      dm3sq=rmsoft(43)
      dm3su=rmsoft(46)
      dm3sd=rmsoft(49)
      dm2sl=rmsoft(32)
      dm2se=rmsoft(35)
      dm2sq=rmsoft(42)
      dm2su=rmsoft(45)
      dm2sd=rmsoft(48)
      dm1sl=rmsoft(31)
      dm1se=rmsoft(34)
      dm1sq=rmsoft(41)
      dm1su=rmsoft(44)
      dm1sd=rmsoft(47)
      ae33=ae(3,3)
      ae22=ae(2,2)
      ae11=ae(1,1)
      au33=au(3,3)
      au22=au(2,2)
      au11=au(1,1)
      ad33=ad(3,3)
      ad22=ad(2,2)
      ad11=ad(1,1)
      CALL fhsetpara(ierr, 1d0, dmt, dmb, dmw, dmz, dtanb,
     &     dma,0d0, dm3sl, dm3se, dm3sq, dm3su, dm3sd,
     &     dm2sl, dm2se, dm2sq, dm2su, dm2sd,
     &     dm1sl, dm1se, dm1sq, dm1su, dm1sd,dmu,
     &     ae33, au33, ad33, ae22, au22, ad22, ae11, au11, ad11,
     &     dm1, dm2, dm3, 0d0, 0d0,q,q,q)
      IF (ierr.NE.0) THEN
        CALL pyerrm(11,'(PYHGGM:) Caught error from FHSETPARA.'
     &       //' Will not use FeynHiggs for this run.')
        RETURN
      ENDIF
C...  Get Higgs masses & alpha_eff. (UHIGGS redundant here, only for CPV)
      saeff=0d0
      CALL fhhiggscorr(ierr, rmhigg, saeff, uhiggs)
      IF (ierr.NE.0) THEN
        CALL pyerrm(11,'(PYFEYN:) Caught error from FHHIG'//
     &       'GSCORR. Will not use FeynHiggs for this run.')
        RETURN
      ENDIF
      alpha = asin(dble(saeff))
      r=rmss(18)/alpha
      IF (r.LT.0d0.OR.abs(r).GT.1.2d0.OR.abs(r).LT.0.8d0) THEN
        CALL pyerrm(1,'(PYFEYN:) Large corrections in Higgs sector.')
        WRITE(mstu(11),*) '   Old Alpha:', rmss(18)
        WRITE(mstu(11),*) '   New Alpha:', alpha
      ENDIF
      IF (rmhigg(1).LT.0.85d0*pmas(25,1).OR.rmhigg(1).GT.
     &       1.15d0*pmas(25,1)) THEN
        CALL pyerrm(1,'(PYFEYN:) Large corrections in Higgs sector.')
        WRITE(mstu(11),*) '   Old m(h0):', pmas(25,1)
        WRITE(mstu(11),*) '   New m(h0):', rmhigg(1)
      ENDIF
      rmss(18)=alpha
      pmas(25,1)=rmhigg(1)
      pmas(35,1)=rmhigg(2)
      pmas(36,1)=rmhigg(3)
      pmas(37,1)=rmhigg(4)
 
      RETURN
      END