atrobo.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file atrobo.f

C
C*******************************************************************
C       make  boost and rotation to entries from IMIN to IMAX
C*******************************************************************
        SUBROUTINE atrobo(THE,PHI,BEX,BEY,BEZ,IMIN,IMAX,IERROR)
        common/lujets/n,k(9000,5),p(9000,5),v(9000,5)
        SAVE  /lujets/
        dimension rot(3,3),pv(3)
        DOUBLE PRECISION dp(4),dbex,dbey,dbez,dga,dga2,dbep,dgabep
        ierror=0
     
        IF(imin.LE.0 .OR. imax.GT.n .OR. imin.GT.imax) RETURN

        IF(the**2+phi**2.GT.1e-20) THEN
C...ROTATE (TYPICALLY FROM Z AXIS TO DIRECTION THETA,PHI)
           rot(1,1)=cos(the)*cos(phi)
           rot(1,2)=-sin(phi)
           rot(1,3)=sin(the)*cos(phi)
           rot(2,1)=cos(the)*sin(phi)
           rot(2,2)=cos(phi)
           rot(2,3)=sin(the)*sin(phi)
           rot(3,1)=-sin(the)
           rot(3,2)=0.
           rot(3,3)=cos(the)
           DO 120 i=imin,imax
C**************    IF(MOD(K(I,1)/10000,10).GE.6) GOTO 120
              DO 100 j=1,3
 100             pv(j)=p(i,j)
                 DO 110 j=1,3
 110                p(i,j)=rot(j,1)*pv(1)+rot(j,2)*pv(2)
     &                     +rot(j,3)*pv(3)
 120             CONTINUE
        ENDIF
     
        IF(bex**2+bey**2+bez**2.GT.1e-20) THEN
C...LORENTZ BOOST (TYPICALLY FROM REST TO MOMENTUM/ENERGY=BETA)
                dbex=bex
                dbey=bey
                dbez=bez
                dga2=1d0-dbex**2-dbey**2-dbez**2
                IF(dga2.LE.0d0) THEN
                        ierror=1
                        RETURN
                ENDIF
                dga=1d0/dsqrt(dga2)
                DO 140 i=imin,imax
C*************     IF(MOD(K(I,1)/10000,10).GE.6) GOTO 140
                   DO 130 j=1,4
130                dp(j)=p(i,j)
                   dbep=dbex*dp(1)+dbey*dp(2)+dbez*dp(3)
                   dgabep=dga*(dga*dbep/(1d0+dga)+dp(4))
                   p(i,1)=dp(1)+dgabep*dbex
                   p(i,2)=dp(2)+dgabep*dbey
                   p(i,3)=dp(3)+dgabep*dbez
                   p(i,4)=dga*(dp(4)+dbep)
140             CONTINUE
        ENDIF
     
        RETURN
        END