pyrvsb.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file pyrvsb.f

 
C*********************************************************************
 
C...PYRVSB
C...Auxiliary function to PYRVSF for calculating R-Violating
C...sfermion widths. Though the decay products are most often treated
C...as massless in the calculation, the kinematical boundary of phase
C...space is tested using the true masses.
C...MODE = 1: All decay products massive
C...MODE = 2: Decay product 1 massless
C...MODE = 3: Decay product 2 massless
C...MODE = 4: All decay products  massless
 
      FUNCTION pyrvsb(KFIN,ID1,ID2,RM2,MODE)
 
      IMPLICIT DOUBLE PRECISION (a-h,o-z)
      IMPLICIT integer(i-n)
      common/pydat1/mstu(200),paru(200),mstj(200),parj(200)
      common/pydat2/kchg(500,4),pmas(500,4),parf(2000),vckm(4,4)
      SAVE /pydat1/,/pydat2/
      DOUBLE PRECISION sm(3)
      INTEGER pycomp, kc(3)
      kc(1)=pycomp(kfin)
      kc(2)=pycomp(id1)
      kc(3)=pycomp(id2)
      sm(1)=pmas(kc(1),1)**2
      sm(2)=pmas(kc(2),1)**2
      sm(3)=pmas(kc(3),1)**2
C...Kinematics check
      IF ((sm(1)-(pmas(kc(2),1)+pmas(kc(3),1))**2).LE.0d0) THEN
        pyrvsb=0d0
        RETURN
      ENDIF
C...CM momenta squared
      IF (mode.EQ.1) THEN
        p2cm=1./(4*sm(1))*(sm(1)-(pmas(kc(2),1)+pmas(kc(3),1))**2)
     &       * (sm(1)-(pmas(kc(2),1)-pmas(kc(3),1))**2)
      ELSE IF (mode.EQ.2) THEN
        p2cm=1./(4*sm(1))*(sm(1)-(pmas(kc(3),1))**2)**2
      ELSE IF (mode.EQ.3) THEN
        p2cm=1./(4*sm(1))*(sm(1)-(pmas(kc(2),1))**2)**2
      ELSE
        p2cm=sm(1)/4.
      ENDIF
C...Calculate Width
      pyrvsb=rm2*sqrt(max(0d0,p2cm))/(8*paru(1)*sm(1))
      RETURN
      END