py1ent.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file py1ent.f

 
C*********************************************************************
 
C...PY1ENT
C...Stores one parton/particle in commonblock PYJETS.
 
      SUBROUTINE py1ent(IP,KF,PE,THE,PHI)
 
C...Double precision and integer declarations.
      IMPLICIT DOUBLE PRECISION(a-h, o-z)
      IMPLICIT INTEGER(i-n)
      INTEGER pyk,pychge,pycomp
C...Commonblocks.
      common/pyjets/n,npad,k(4000,5),p(4000,5),v(4000,5)
      common/pydat1/mstu(200),paru(200),mstj(200),parj(200)
      common/pydat2/kchg(500,4),pmas(500,4),parf(2000),vckm(4,4)
      SAVE /pyjets/,/pydat1/,/pydat2/
 
C...Standard checks.
      mstu(28)=0
      IF(mstu(12).NE.12345) CALL pylist(0)
      ipa=max(1,iabs(ip))
      IF(ipa.GT.mstu(4)) CALL pyerrm(21,
     &'(PY1ENT:) writing outside PYJETS memory')
      kc=pycomp(kf)
      IF(kc.EQ.0) CALL pyerrm(12,'(PY1ENT:) unknown flavour code')
 
C...Find mass. Reset K, P and V vectors.
      pm=0d0
      IF(mstu(10).EQ.1) pm=p(ipa,5)
      IF(mstu(10).GE.2) pm=pymass(kf)
      DO 100 j=1,5
        k(ipa,j)=0
        p(ipa,j)=0d0
        v(ipa,j)=0d0
  100 CONTINUE
 
C...Store parton/particle in K and P vectors.
      k(ipa,1)=1
      IF(ip.LT.0) k(ipa,1)=2
      k(ipa,2)=kf
      p(ipa,5)=pm
      p(ipa,4)=max(pe,pm)
      pa=sqrt(p(ipa,4)**2-p(ipa,5)**2)
      p(ipa,1)=pa*sin(the)*cos(phi)
      p(ipa,2)=pa*sin(the)*sin(phi)
      p(ipa,3)=pa*cos(the)
 
C...Set N. Optionally fragment/decay.
      n=ipa
      IF(ip.EQ.0) CALL pyexec
 
      RETURN
      END