pyfram.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file pyfram.f

 
C*********************************************************************
 
C...PYFRAM
C...Performs transformations between different coordinate frames.
 
      SUBROUTINE pyfram(IFRAME)
 
C...Double precision and integer declarations.
      IMPLICIT DOUBLE PRECISION(a-h, o-z)
      IMPLICIT INTEGER(i-n)
      INTEGER pyk,pychge,pycomp
C...Commonblocks.
      common/pydat1/mstu(200),paru(200),mstj(200),parj(200)
      common/pypars/mstp(200),parp(200),msti(200),pari(200)
      common/pyint1/mint(400),vint(400)
      SAVE /pydat1/,/pypars/,/pyint1/
 
C...Check that transformation can and should be done.
      IF(iframe.EQ.1.OR.iframe.EQ.2.OR.(iframe.EQ.3.AND.
     &mint(91).EQ.1)) THEN
        IF(iframe.EQ.mint(6)) RETURN
      ELSE
        WRITE(mstu(11),5000) iframe,mint(6)
        RETURN
      ENDIF
 
      IF(mint(6).EQ.1) THEN
C...Transform from fixed target or user specified frame to
C...overall CM frame.
        CALL pyrobo(0,0,0d0,0d0,-vint(8),-vint(9),-vint(10))
        CALL pyrobo(0,0,0d0,-vint(7),0d0,0d0,0d0)
        CALL pyrobo(0,0,-vint(6),0d0,0d0,0d0,0d0)
      ELSEIF(mint(6).EQ.3) THEN
C...Transform from hadronic CM frame in DIS to overall CM frame.
        CALL pyrobo(0,0,-vint(221),-vint(222),-vint(223),-vint(224),
     &  -vint(225))
      ENDIF
 
      IF(iframe.EQ.1) THEN
C...Transform from overall CM frame to fixed target or user specified
C...frame.
        CALL pyrobo(0,0,vint(6),vint(7),vint(8),vint(9),vint(10))
      ELSEIF(iframe.EQ.3) THEN
C...Transform from overall CM frame to hadronic CM frame in DIS.
        CALL pyrobo(0,0,0d0,0d0,vint(223),vint(224),vint(225))
        CALL pyrobo(0,0,0d0,vint(222),0d0,0d0,0d0)
        CALL pyrobo(0,0,vint(221),0d0,0d0,0d0,0d0)
      ENDIF
 
C...Set information about new frame.
      mint(6)=iframe
      msti(6)=iframe
 
 5000 FORMAT(1x,'Error: illegal values in subroutine PYFRAM.',1x,
     &'No transformation performed.'/1x,'IFRAME =',1x,i5,'; MINT(6) =',
     &1x,i5)
 
      RETURN
      END