pycomp.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file pycomp.f

 
C*********************************************************************
 
C...PYCOMP
C...Compress the standard KF codes for use in mass and decay arrays;
C...also checks whether a given code actually is defined.
 
      FUNCTION pycomp(KF)
 
C...Double precision and integer declarations.
      IMPLICIT DOUBLE PRECISION(a-h, o-z)
      IMPLICIT INTEGER(i-n)
      INTEGER pyk,pychge,pycomp
C...Commonblocks.
      common/pydat1/mstu(200),paru(200),mstj(200),parj(200)
      common/pydat2/kchg(500,4),pmas(500,4),parf(2000),vckm(4,4)
      SAVE /pydat1/,/pydat2/
C...Local arrays and saved data.
      dimension kford(100:500),kcord(101:500)
      SAVE kford,kcord,nford,kflast,kclast
 
C...Whenever necessary reorder codes for faster search.
      IF(mstu(20).EQ.0) THEN
        nford=100
        kford(100)=0
        DO 120 i=101,500
          kfa=kchg(i,4)
          IF(kfa.LE.100) goto 120
          nford=nford+1
          DO 100 i1=nford-1,0,-1
            IF(kfa.GE.kford(i1)) goto 110
            kford(i1+1)=kford(i1)
            kcord(i1+1)=kcord(i1)
  100     CONTINUE
  110     kford(i1+1)=kfa
          kcord(i1+1)=i
  120   CONTINUE
        mstu(20)=1
        kflast=0
        kclast=0
      ENDIF
 
C...Fast action if same code as in latest call.
      IF(kf.EQ.kflast) THEN
        pycomp=kclast
        RETURN
      ENDIF
 
C...Starting values. Remove internal diquark flags.
      pycomp=0
      kfa=iabs(kf)
      IF(mod(kfa/10,10).EQ.0.AND.kfa.LT.100000
     &     .AND.mod(kfa/1000,10).GT.0) kfa=mod(kfa,10000)
 
C...Simple cases: direct translation.
      IF(kfa.GT.kford(nford)) THEN
      ELSEIF(kfa.LE.100) THEN
        pycomp=kfa
 
C...Else binary search.
      ELSE
        imin=100
        imax=nford+1
  130   iavg=(imin+imax)/2
        IF(kford(iavg).GT.kfa) THEN
          imax=iavg
          IF(imax.GT.imin+1) goto 130
        ELSEIF(kford(iavg).LT.kfa) THEN
          imin=iavg
          IF(imax.GT.imin+1) goto 130
        ELSE
          pycomp=kcord(iavg)
        ENDIF
      ENDIF
 
C...Check if antiparticle allowed.
      IF(pycomp.NE.0.AND.kf.LT.0) THEN
        IF(kchg(pycomp,3).EQ.0) pycomp=0
      ENDIF
 
C...Save codes for possible future fast action.
      kflast=kf
      kclast=pycomp
 
      RETURN
      END