d1/db6/pycba2_8f_source.html

C*********************************************************************


C...PYCBA2

C...Auxiliary to PYEICG.

C

C     THIS SUBROUTINE IS A TRANSLATION OF THE ALGOL PROCEDURE

C     CBABK2, WHICH IS A COMPLEX VERSION OF BALBAK,

C     NUM. MATH. 13, 293-304(1969) BY PARLETT AND REINSCH.

C     HANDBOOK FOR AUTO. COMP., VOL.II-LINEAR ALGEBRA, 315-326(1971).

C

C     THIS SUBROUTINE FORMS THE EIGENVECTORS OF A COMPLEX GENERAL

C     MATRIX BY BACK TRANSFORMING THOSE OF THE CORRESPONDING

C     BALANCED MATRIX DETERMINED BY  CBAL.

C

C     ON INPUT

C

C        NM MUST BE SET TO THE ROW DIMENSION OF TWO-DIMENSIONAL

C          ARRAY PARAMETERS AS DECLARED IN THE CALLING PROGRAM

C          DIMENSION STATEMENT.

C

C        N IS THE ORDER OF THE MATRIX.

C

C        LOW AND IGH ARE INTEGERS DETERMINED BY  CBAL.

C

C        SCALE CONTAINS INFORMATION DETERMINING THE PERMUTATIONS

C          AND SCALING FACTORS USED BY  CBAL.

C

C        M IS THE NUMBER OF EIGENVECTORS TO BE BACK TRANSFORMED.

C

C        ZR AND ZI CONTAIN THE REAL AND IMAGINARY PARTS,

C          RESPECTIVELY, OF THE EIGENVECTORS TO BE

C          BACK TRANSFORMED IN THEIR FIRST M COLUMNS.

C

C     ON OUTPUT

C

C        ZR AND ZI CONTAIN THE REAL AND IMAGINARY PARTS,

C          RESPECTIVELY, OF THE TRANSFORMED EIGENVECTORS

C          IN THEIR FIRST M COLUMNS.

C

C     QUESTIONS AND COMMENTS SHOULD BE DIRECTED TO BURTON S. GARBOW,

C     MATHEMATICS AND COMPUTER SCIENCE DIV, ARGONNE NATIONAL LABORATORY

C

C     THIS VERSION DATED AUGUST 1983.

C


      SUBROUTINE pycba2(NM,N,LOW,IGH,SCALE,M,ZR,ZI)


      INTEGER i,j,k,m,n,ii,nm,igh,low

      DOUBLE PRECISION scale(4),zr(4,4),zi(4,4)

      DOUBLE PRECISION s


      IF (m .EQ. 0) goto 150

      IF (igh .EQ. low) goto 120

C

      DO 110 i = low, igh

         s = scale(i)

C     .......... LEFT HAND EIGENVECTORS ARE BACK TRANSFORMED

C                IF THE FOREGOING STATEMENT IS REPLACED BY

C                S=1.0D0/SCALE(I). ..........

         DO 100 j = 1, m

            zr(i,j) = zr(i,j) * s

            zi(i,j) = zi(i,j) * s

  100    CONTINUE

C

  110 CONTINUE

C     .......... FOR I=LOW-1 STEP -1 UNTIL 1,

C                IGH+1 STEP 1 UNTIL N DO -- ..........

  120 DO 140 ii = 1, n

         i = ii

         IF (i .GE. low .AND. i .LE. igh) goto 140

         IF (i .LT. low) i = low - ii

         k = scale(i)

         IF (k .EQ. i) goto 140

C

         DO 130 j = 1, m

            s = zr(i,j)

            zr(i,j) = zr(k,j)

            zr(k,j) = s

            s = zi(i,j)

            zi(i,j) = zi(k,j)

            zi(k,j) = s

  130    CONTINUE

C

  140 CONTINUE

C

  150 RETURN

      END