pyxxz6.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file pyxxz6.f

 
C*********************************************************************
 
C...PYXXZ6
C...Used in the calculation of  inoi -> inoj + f + ~f.
 
      FUNCTION pyxxz6(X)
 
C...Double precision and integer declarations.
      IMPLICIT DOUBLE PRECISION(a-h, o-z)
      IMPLICIT INTEGER(i-n)
      INTEGER pyk,pychge,pycomp
C...Parameter statement to help give large particle numbers.
      parameter(ksusy1=1000000,ksusy2=2000000,ktechn=3000000,
     &kexcit=4000000,kdimen=5000000)
C...Commonblocks.
      common/pydat1/mstu(200),paru(200),mstj(200),parj(200)
C      COMMON/PYINTS/XXM(20)
      COMPLEX*16 cxc
      common/pyintc/xxc(10),cxc(8)
      SAVE /pydat1/,/pyintc/
 
C...Local variables.
      COMPLEX*16 qlls,qrrs,qrls,qlrs,qllu,qrru,qlrt,qrlt
      DOUBLE PRECISION pyxxz6,x
      DOUBLE PRECISION xm12,xm22,xm32,s,s13,wprop2
      DOUBLE PRECISION ww,wf1,wf2,wfl1,wfl2
      DOUBLE PRECISION sij
      DOUBLE PRECISION xmv,xmg,xmsu1,xmsu2,xmsd1,xmsd2
      DOUBLE PRECISION ol2
      DOUBLE PRECISION s23min,s23max,s23ave,s23del
      INTEGER i
 
C...Statement functions.
C...Integral from x to y of (t-a)(b-t) dt.
      tint(x,y,a,b)=(x-y)*(-(x**2+x*y+y**2)/3d0+(b+a)*(x+y)/2d0-a*b)
C...Integral from x to y of (t-a)(b-t)/(t-c) dt.
      tint2(x,y,a,b,c)=(x-y)*(-0.5d0*(x+y)+(b+a-c))-
     &log(abs((x-c)/(y-c)))*(c-b)*(c-a)
C...Integral from x to y of (t-a)(b-t)/(t-c)**2 dt.
      tint3(x,y,a,b,c)=-(x-y)+(c-a)*(c-b)*(y-x)/(x-c)/(y-c)+
     &(b+a-2d0*c)*log(abs((x-c)/(y-c)))
C...Integral from x to y of (t-a)/(b-t) dt.
      utint(x,y,a,b)=log(abs((x-a)/(b-x)*(b-y)/(y-a)))/(b-a)
C...Integral from x to y of 1/(t-a) dt.
      tprop(x,y,a)=log(abs((x-a)/(y-a)))
 
      xm12=xxc(1)**2
      xm22=xxc(2)**2
      xm32=xxc(3)**2
      s=xxc(4)**2
      s13=x
 
      s23ave=xm22+xm32-0.5d0/x*(x+xm32-xm12)*(x+xm22-s)
      s23del=0.5d0/x*sqrt( ( (x-xm12-xm32)**2-4d0*xm12*xm32)*
     &( (x-xm22-s)**2  -4d0*xm22*s  ) )
 
      s23min=(s23ave-s23del)
      s23max=(s23ave+s23del)
 
      xmsd1=xxc(5)**2
      xmsd2=xxc(7)**2
      xmsu1=xxc(6)**2
      xmsu2=xxc(8)**2
 
      xmv=xxc(9)
      xmg=xxc(10)
      qlls=cxc(1)
      qllu=cxc(2)
      qlrs=cxc(3)
      qlrt=cxc(4)
      qrls=cxc(5)
      qrlt=cxc(6)
      qrrs=cxc(7)
      qrru=cxc(8)
      wprop2=(s13-xmv**2)**2+(xmv*xmg)**2
      sij=2d0*xxc(2)*xxc(4)*s13
      IF(xmv.LE.1000d0) THEN
        ol2=abs(qlls)**2+abs(qrrs)**2+abs(qlrs)**2+abs(qrls)**2
        olr=-2d0*dble(qlrs*dconjg(qlls)+qrls*dconjg(qrrs))
        ww=(ol2*2d0*tint(s23max,s23min,xm22,s)
     &  +olr*sij*(s23max-s23min))/wprop2
        IF(xxc(5).LE.10000d0) THEN
          wfl1=4d0*(dble(qlls*dconjg(qllu))*
     &    tint2(s23max,s23min,xm22,s,xmsd1)-
     &    .5d0*dble(qlls*dconjg(qlrt))*sij*tprop(s23max,s23min,xmsd2)+
     &    dble(qlrs*dconjg(qlrt))*tint2(s23max,s23min,xm22,s,xmsd2)-
     &    .5d0*dble(qlrs*dconjg(qllu))*sij*tprop(s23max,s23min,xmsd1))
     &    *(s13-xmv**2)/wprop2
        ELSE
          wfl1=0d0
        ENDIF
 
        IF(xxc(6).LE.10000d0) THEN
          wfl2=4d0*(dble(qrrs*dconjg(qrru))*
     &    tint2(s23max,s23min,xm22,s,xmsu1)-
     &    .5d0*dble(qrrs*dconjg(qrlt))*sij*tprop(s23max,s23min,xmsu2)+
     &    dble(qrls*dconjg(qrlt))*tint2(s23max,s23min,xm22,s,xmsu2)-
     &    .5d0*dble(qrls*dconjg(qrru))*sij*tprop(s23max,s23min,xmsu1))
     &    *(s13-xmv**2)/wprop2
        ELSE
          wfl2=0d0
        ENDIF
      ELSE
        ww=0d0
        wfl1=0d0
        wfl2=0d0
      ENDIF
      IF(xxc(5).LE.10000d0) THEN
        wf1=2d0*abs(qllu)**2*tint3(s23max,s23min,xm22,s,xmsd1)
     &  +2d0*abs(qlrt)**2*tint3(s23max,s23min,xm22,s,xmsd2)
     &  - 2d0*dble(qlrt*dconjg(qllu))*
     &  sij*utint(s23max,s23min,xmsd1,xm22+s-s13-xmsd2)
      ELSE
        wf1=0d0
      ENDIF
      IF(xxc(6).LE.10000d0) THEN
        wf2=2d0*abs(qrru)**2*tint3(s23max,s23min,xm22,s,xmsu1)
     &  +2d0*abs(qrlt)**2*tint3(s23max,s23min,xm22,s,xmsu2)
     &  - 2d0*dble(qrlt*dconjg(qrru))*
     &  sij*utint(s23max,s23min,xmsu1,xm22+s-s13-xmsu2)
      ELSE
        wf2=0d0
      ENDIF
 
      pyxxz6=(ww+wf1+wf2+wfl1+wfl2)
 
      IF(pyxxz6.LT.0d0) THEN
        WRITE(mstu(11),*) ' NEGATIVE WT IN PYXXZ6 '
        WRITE(mstu(11),*) xxc(1),xxc(2),xxc(3),xxc(4)
        WRITE(mstu(11),*) (xxc(i),i=5,8)
        WRITE(mstu(11),*) (xxc(i),i=9,12)
        WRITE(mstu(11),*) (xxc(i),i=13,16)
        WRITE(mstu(11),*) ww,wf1,wf2,wfl1,wfl2
        WRITE(mstu(11),*) s23min,s23max
        pyxxz6=0d0
      ENDIF
 
      RETURN
      END