pyalem.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file pyalem.f

 
C*********************************************************************
 
C...PYALEM
C...Calculates the running alpha_electromagnetic.
 
      FUNCTION pyalem(Q2)
 
C...Double precision and integer declarations.
      IMPLICIT DOUBLE PRECISION(a-h, o-z)
      IMPLICIT INTEGER(i-n)
      INTEGER pyk,pychge,pycomp
C...Commonblocks.
      common/pydat1/mstu(200),paru(200),mstj(200),parj(200)
      SAVE /pydat1/
 
C...Calculate real part of photon vacuum polarization.
C...For leptons simplify by using asymptotic (Q^2 >> m^2) expressions.
C...For hadrons use parametrization of H. Burkhardt et al.
C...See R. Kleiss et al, CERN 89-08, vol. 3, pp. 129-131.
      aempi=paru(101)/(3d0*paru(1))
      IF(mstu(101).LE.0.OR.q2.LT.2d-6) THEN
        rpigg=0d0
      ELSEIF(mstu(101).EQ.2.AND.q2.LT.paru(104)) THEN
        rpigg=0d0
      ELSEIF(mstu(101).EQ.2) THEN
        rpigg=1d0-paru(101)/paru(103)
      ELSEIF(q2.LT.0.09d0) THEN
        rpigg=aempi*(13.4916d0+log(q2))+0.00835d0*log(1d0+q2)
      ELSEIF(q2.LT.9d0) THEN
        rpigg=aempi*(16.3200d0+2d0*log(q2))+
     &  0.00238d0*log(1d0+3.927d0*q2)
      ELSEIF(q2.LT.1d4) THEN
        rpigg=aempi*(13.4955d0+3d0*log(q2))+0.00165d0+
     &  0.00299d0*log(1d0+q2)
      ELSE
        rpigg=aempi*(13.4955d0+3d0*log(q2))+0.00221d0+
     &  0.00293d0*log(1d0+q2)
      ENDIF
 
C...Calculate running alpha_em.
      pyalem=paru(101)/(1d0-rpigg)
      paru(108)=pyalem
 
      RETURN
      END