pybook.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file pybook.f

 
C*********************************************************************
 
C...PYBOOK
C...Books a histogram.
 
      SUBROUTINE pybook(ID,TITLE,NX,XL,XU)
 
C...Double precision declaration.
      IMPLICIT DOUBLE PRECISION(a-h, o-z)
      IMPLICIT INTEGER(i-n)
C...Commonblock.
      common/pybins/ihist(4),indx(1000),bin(20000)
      SAVE /pybins/
C...Local character variables.
      CHARACTER title*(*), titfx*60
 
C...Check that input is sensible. Find initial address in memory.
      IF(id.LE.0.OR.id.GT.ihist(1)) CALL pyerrm(28,
     &'(PYBOOK:) not allowed histogram number')
      IF(nx.LE.0.OR.nx.GT.100) CALL pyerrm(28,
     &'(PYBOOK:) not allowed number of bins')
      IF(xl.GE.xu) CALL pyerrm(28,
     &'(PYBOOK:) x limits in wrong order')
      indx(id)=ihist(4)
      ihist(4)=ihist(4)+28+nx
      IF(ihist(4).GT.ihist(2)) CALL pyerrm(28,
     &'(PYBOOK:) out of histogram space')
      is=indx(id)
 
C...Store histogram size and reset contents.
      bin(is+1)=nx
      bin(is+2)=xl
      bin(is+3)=xu
      bin(is+4)=(xu-xl)/nx
      CALL pynull(id)
 
C...Store title by conversion to integer to double precision.
      titfx=title//' '
      DO 100 it=1,20
        bin(is+8+nx+it)=256**2*ichar(titfx(3*it-2:3*it-2))+
     &  256*ichar(titfx(3*it-1:3*it-1))+ichar(titfx(3*it:3*it))
  100 CONTINUE
 
      RETURN
      END