pystbh.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file pystbh.f

 
C*********************************************************************
 
C...PYSTBH (and auxiliaries)
C.. Evaluates the matrix elements for t + b + H production.
 
      SUBROUTINE pystbh(WTTBH)
 
C...DOUBLE PRECISION AND INTEGER DECLARATIONS
      IMPLICIT DOUBLE PRECISION(a-h, o-z)
      IMPLICIT INTEGER(i-n)
      INTEGER pyk,pychge,pycomp
 
C...COMMONBLOCKS
      common/pydat1/mstu(200),paru(200),mstj(200),parj(200)
      common/pydat2/kchg(500,4),pmas(500,4),parf(2000),vckm(4,4)
      common/pypars/mstp(200),parp(200),msti(200),pari(200)
      common/pyint1/mint(400),vint(400)
      common/pyint2/iset(500),kfpr(500,2),coef(500,20),icol(40,4,2)
      common/pyint3/xsfx(2,-40:40),isig(1000,3),sigh(1000)
      common/pyint4/mwid(500),wids(500,5)
      common/pysubs/msel,mselpd,msub(500),kfin(2,-40:40),ckin(200)
      common/pymssm/imss(0:99),rmss(0:99)
      common/pysgcm/isub,isubsv,mmin1,mmax1,mmin2,mmax2,mmina,mmaxa,
     &kfac(2,-40:40),comfac,fack,faca,sh,th,uh,sh2,th2,uh2,sqm3,sqm4,
     &shr,sqpth,taup,be34,cth,x(2),sqmz,sqmw,gmmz,gmmw,
     &aem,as,xw,xw1,xwc,xwv,poll,polr,polll,polrr
      common/pyctbh/ alpha,alphas,sw2,mw2,tanb,vtb,v,a
      DOUBLE PRECISION mw2
      SAVE /pydat1/,/pydat2/,/pypars/,/pyint1/,/pyint2/,/pyint3/,
     &/pyint4/,/pysubs/,/pymssm/,/pysgcm/,/pyctbh/
 
C...LOCAL ARRAYS AND COMPLEX VARIABLES
      dimension qq(4,2),pp(4,3)
      DATA qq/8*0d0/
 
      wttbh=0d0
 
C...KINEMATIC PARAMETERS.
      shpr=sqrt(vint(26))*vint(1)
      ph=sqrt(vint(21))*vint(1)
      sph=ph**2
 
C...SET UP OUTGOING KINEMATICS: 1=T, 2=TBAR, 3=H.
      DO 100 i=1,2
        pt=sqrt(max(0d0,vint(197+5*i)))
        pp(1,i)=pt*cos(vint(198+5*i))
        pp(2,i)=pt*sin(vint(198+5*i))
  100 CONTINUE
      pp(1,3)=-pp(1,1)-pp(1,2)
      pp(2,3)=-pp(2,1)-pp(2,2)
      pms1=vint(201)**2+pp(1,1)**2+pp(2,1)**2
      pms2=vint(206)**2+pp(1,2)**2+pp(2,2)**2
      pms3=sph+pp(1,3)**2+pp(2,3)**2
      pmt3=sqrt(pms3)
      pp(3,3)=pmt3*sinh(vint(211))
      pp(4,3)=pmt3*cosh(vint(211))
      pms12=(shpr-pp(4,3))**2-pp(3,3)**2
      pp(3,1)=(-pp(3,3)*(pms12+pms1-pms2)+
     &vint(213)*(shpr-pp(4,3))*vint(220))/(2d0*pms12)
      pp(3,2)=-pp(3,1)-pp(3,3)
      pp(4,1)=sqrt(pms1+pp(3,1)**2)
      pp(4,2)=sqrt(pms2+pp(3,2)**2)
 
C...CM SYSTEM, INGOING QUARKS/GLUONS
      qq(3,1) = shpr/2.d0
      qq(4,1) = qq(3,1)
      qq(3,2) = -qq(3,1)
      qq(4,2) = qq(4,1)
 
C...PARAMETERS FOR AMPLITUDE METHOD
      alpha = aem
      alphas = as
      sw2 = paru(102)
      mw2 = pmas(24,1)**2
      tanb = paru(141)
      vtb = vckm(3,3)
      rmb=pymrun(5,vint(52))
 
      isub=mint(1)
 
      IF (isub.EQ.401) THEN
        CALL pytbhg(qq(1,1),qq(1,2),pp(1,1),pp(1,2),pp(1,3),
     &  vint(201),vint(206),rmb,vint(43),wttbh)
      ELSE IF (isub.EQ.402) THEN
        CALL pytbhq(qq(1,1),qq(1,2),pp(1,1),pp(1,2),pp(1,3),
     &  vint(201),vint(206),rmb,vint(43),wttbh)
      END IF
 
      RETURN
      END