pylhef.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file pylhef.f

C*********************************************************************

C...Combine the two old-style Pythia initialization and event files
C...into a single Les Houches Event File.

      SUBROUTINE pylhef
 
C...Double precision and integer declarations.
      IMPLICIT DOUBLE PRECISION(a-h, o-z)
      IMPLICIT INTEGER(i-n)
 
C...PYTHIA commonblock: only used to provide read/write units and version.
      common/pypars/mstp(200),parp(200),msti(200),pari(200)
      SAVE /pypars/
 
C...User process initialization commonblock.
      INTEGER maxpup
      parameter(maxpup=100)
      INTEGER idbmup,pdfgup,pdfsup,idwtup,nprup,lprup
      DOUBLE PRECISION ebmup,xsecup,xerrup,xmaxup
      common/heprup/idbmup(2),ebmup(2),pdfgup(2),pdfsup(2),
     &idwtup,nprup,xsecup(maxpup),xerrup(maxpup),xmaxup(maxpup),
     &lprup(maxpup)
      SAVE /heprup/
 
C...User process event common block.
      INTEGER maxnup
      parameter(maxnup=500)
      INTEGER nup,idprup,idup,istup,mothup,icolup
      DOUBLE PRECISION xwgtup,scalup,aqedup,aqcdup,pup,vtimup,spinup
      common/hepeup/nup,idprup,xwgtup,scalup,aqedup,aqcdup,idup(maxnup),
     &istup(maxnup),mothup(2,maxnup),icolup(2,maxnup),pup(5,maxnup),
     &vtimup(maxnup),spinup(maxnup)
      SAVE /hepeup/

C...Lines to read in assumed never longer than 200 characters. 
      parameter(maxlen=200)
      CHARACTER*(MAXLEN) string

C...Format for reading lines.
      CHARACTER*6 strfmt
      strfmt='(A000)'
      WRITE(strfmt(3:5),'(I3)') maxlen

C...Rewind initialization and event files. 
      rewind mstp(161)
      rewind mstp(162)

C...Write header info.
      WRITE(mstp(163),'(A)') '<LesHouchesEvents version="1.0">'
      WRITE(mstp(163),'(A)') '<!--'
      WRITE(mstp(163),'(A,I1,A1,I3)') 'File generated with PYTHIA ',
     &mstp(181),'.',mstp(182)
      WRITE(mstp(163),'(A)') '-->'       

C...Read first line of initialization info and get number of processes.
      READ(mstp(161),'(A)',end=400,err=400) string                  
      READ(string,*,err=400) idbmup(1),idbmup(2),ebmup(1),
     &ebmup(2),pdfgup(1),pdfgup(2),pdfsup(1),pdfsup(2),idwtup,nprup

C...Copy initialization lines, omitting trailing blanks. 
C...Embed in <init> ... </init> block.
      WRITE(mstp(163),'(A)') '<init>' 
      DO 140 ipr=0,nprup
        IF(ipr.GT.0) READ(mstp(161),'(A)',end=400,err=400) string
        len=maxlen+1  
  120   len=len-1
        IF(len.GT.1.AND.string(len:len).EQ.' ') goto 120
        WRITE(mstp(163),'(A)',err=400) string(1:len)
  140 CONTINUE
      WRITE(mstp(163),'(A)') '</init>' 

C...Begin event loop. Read first line of event info or already done.
      READ(mstp(162),'(A)',end=320,err=400) string    
  200 CONTINUE

C...Look at first line to know number of particles in event.
      READ(string,*,err=400) nup,idprup,xwgtup,scalup,aqedup,aqcdup

C...Begin an <event> block. Copy event lines, omitting trailing blanks. 
      WRITE(mstp(163),'(A)') '<event>' 
      DO 240 i=0,nup
        IF(i.GT.0) READ(mstp(162),'(A)',end=400,err=400) string
        len=maxlen+1  
  220   len=len-1
        IF(len.GT.1.AND.string(len:len).EQ.' ') goto 220
        WRITE(mstp(163),'(A)',err=400) string(1:len)
  240 CONTINUE
              
C...Copy trailing comment lines - with a # in the first column - as is.
  260 READ(mstp(162),'(A)',end=300,err=400) string    
      IF(string(1:1).EQ.'#') THEN
        len=maxlen+1  
  280   len=len-1
        IF(len.GT.1.AND.string(len:len).EQ.' ') goto 280
        WRITE(mstp(163),'(A)',err=400) string(1:len)
        goto 260
      ENDIF

C..End the <event> block. Loop back to look for next event.
      WRITE(mstp(163),'(A)') '</event>' 
      goto 200

C...Successfully reached end of event loop: write closing tag
C...and remove temporary intermediate files (unless asked not to).
  300 WRITE(mstp(163),'(A)') '</event>' 
  320 WRITE(mstp(163),'(A)') '</LesHouchesEvents>' 
      IF(mstp(164).EQ.1) RETURN
      CLOSE(mstp(161),err=400,status='DELETE')
      CLOSE(mstp(162),err=400,status='DELETE')
      RETURN

C...Error exit.
  400 WRITE(*,*) ' PYLHEF file joining failed!'

      RETURN
      END