pyrnmq.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file pyrnmq.f

 
C*********************************************************************
 
C...PYRNMQ
C...Determines the running mass of Squarks.
 
      FUNCTION pyrnmq(ID,DTERM)
 
C...Double precision and integer declarations.
      IMPLICIT DOUBLE PRECISION(a-h, o-z)
      IMPLICIT INTEGER(i-n)
      INTEGER pyk,pychge,pycomp
C...Commonblock.
      common/pymssm/imss(0:99),rmss(0:99)
      SAVE /pymssm/
 
C...Local variables.
      DOUBLE PRECISION pi,r
      DOUBLE PRECISION tol
      DOUBLE PRECISION ci(3)
      EXTERNAL pyalps
      DOUBLE PRECISION pyalps
      DATA tol/0.001d0/
      DATA pi,r/3.141592654d0,.61803399d0/
      DATA ci/0.47d0,0.07d0,0.02d0/
 
      c=1d0-r
      ca=ci(id)
      ag=(0.71d0)**2/4d0/pi
      ag=rmss(20)
      xm0=rmss(8)
      xmg=rmss(1)
      xm02=xm0*xm0
      xmg2=xmg*xmg
 
      as=pyalps(xm02+6d0*xmg2)
      cg=8d0/9d0*((as/ag)**2-1d0)
      bx=xm02+(ca+cg)*xmg2+dterm
      ax=min(50d0**2,0.5d0*bx)
      cx=max(2000d0**2,2d0*bx)
 
      x0=ax
      x3=cx
      IF(abs(cx-bx).GT.abs(bx-ax))THEN
        x1=bx
        x2=bx+c*(cx-bx)
      ELSE
        x2=bx
        x1=bx-c*(bx-ax)
      ENDIF
      as1=pyalps(x1)
      cg=8d0/9d0*((as1/ag)**2-1d0)
      f1=abs(xm02+(ca+cg)*xmg2+dterm-x1)
      as2=pyalps(x2)
      cg=8d0/9d0*((as2/ag)**2-1d0)
      f2=abs(xm02+(ca+cg)*xmg2+dterm-x2)
  100 IF(abs(x3-x0).GT.tol*(abs(x1)+abs(x2))) THEN
        IF(f2.LT.f1) THEN
          x0=x1
          x1=x2
          x2=r*x1+c*x3
          f1=f2
          as2=pyalps(x2)
          cg=8d0/9d0*((as2/ag)**2-1d0)
          f2=abs(xm02+(ca+cg)*xmg2+dterm-x2)
        ELSE
          x3=x2
          x2=x1
          x1=r*x2+c*x0
          f2=f1
          as1=pyalps(x1)
          cg=8d0/9d0*((as1/ag)**2-1d0)
          f1=abs(xm02+(ca+cg)*xmg2+dterm-x1)
        ENDIF
        goto 100
      ENDIF
      IF(f1.LT.f2) THEN
        pyrnmq=x1
        xmin=x1
      ELSE
        pyrnmq=x2
        xmin=x2
      ENDIF
 
      RETURN
      END