pyalps.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file pyalps.f

 
C*********************************************************************
 
C...PYALPS
C...Gives the value of alpha_strong.
 
      FUNCTION pyalps(Q2)
 
C...Double precision and integer declarations.
      IMPLICIT DOUBLE PRECISION(a-h, o-z)
      IMPLICIT INTEGER(i-n)
      INTEGER pyk,pychge,pycomp
C...Commonblocks.
      common/pydat1/mstu(200),paru(200),mstj(200),parj(200)
      common/pydat2/kchg(500,4),pmas(500,4),parf(2000),vckm(4,4)
      SAVE /pydat1/,/pydat2/
C...Coefficients for second-order threshold matching.
C...From W.J. Marciano, Phys. Rev. D29 (1984) 580.
      dimension stepdn(6),stepup(6)
c      DATA STEPDN/0D0,0D0,(2D0*107D0/2025D0),(2D0*963D0/14375D0),
c     &(2D0*321D0/3703D0),0D0/
c      DATA STEPUP/0D0,0D0,0D0,(-2D0*107D0/1875D0),
c     &(-2D0*963D0/13225D0),(-2D0*321D0/3381D0)/
      DATA stepdn/0d0,0d0,0.10568d0,0.13398d0,0.17337d0,0d0/
      DATA stepup/0d0,0d0,0d0,-0.11413d0,-0.14563d0,-0.18988d0/
 
C...Constant alpha_strong trivial. Pick artificial Lambda.
      IF(mstu(111).LE.0) THEN
        pyalps=paru(111)
        mstu(118)=mstu(112)
        paru(117)=0.2d0
        IF(q2.GT.0.04d0) paru(117)=sqrt(q2)*exp(-6d0*paru(1)/
     &  ((33d0-2d0*mstu(112))*paru(111)))
        paru(118)=paru(111)
        RETURN
      ENDIF
 
C...Find effective Q2, number of flavours and Lambda.
      q2eff=q2
      IF(mstu(115).GE.2) q2eff=max(q2,paru(114))
      nf=mstu(112)
      alam2=paru(112)**2
  100 IF(nf.GT.max(3,mstu(113))) THEN
        q2thr=paru(113)*pmas(nf,1)**2
        IF(q2eff.LT.q2thr) THEN
          nf=nf-1
          q2rat=q2thr/alam2
          alam2=alam2*q2rat**(2d0/(33d0-2d0*nf))
          IF(mstu(111).EQ.2) alam2=alam2*log(q2rat)**stepdn(nf)
          goto 100
        ENDIF
      ENDIF
  110 IF(nf.LT.min(6,mstu(114))) THEN
        q2thr=paru(113)*pmas(nf+1,1)**2
        IF(q2eff.GT.q2thr) THEN
          nf=nf+1
          q2rat=q2thr/alam2
          alam2=alam2*q2rat**(-2d0/(33d0-2d0*nf))
          IF(mstu(111).EQ.2) alam2=alam2*log(q2rat)**stepup(nf)
          goto 110
        ENDIF
      ENDIF
      IF(mstu(115).EQ.1) q2eff=q2eff+alam2
      paru(117)=sqrt(alam2)
 
C...Evaluate first or second order alpha_strong.
      b0=(33d0-2d0*nf)/6d0
      algq=log(max(1.0001d0,q2eff/alam2))
      IF(mstu(111).EQ.1) THEN
        pyalps=min(paru(115),paru(2)/(b0*algq))
      ELSE
        b1=(153d0-19d0*nf)/6d0
        pyalps=min(paru(115),paru(2)/(b0*algq)*(1d0-b1*log(algq)/
     &  (b0**2*algq)))
      ENDIF
      mstu(118)=nf
      paru(118)=pyalps
 
      RETURN
      END