pyjoin.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file pyjoin.f

 
C*********************************************************************
 
C...PYJOIN
C...Connects a sequence of partons with colour flow indices,
C...as required for subsequent shower evolution (or other operations).
 
      SUBROUTINE pyjoin(NJOIN,IJOIN)
 
C...Double precision and integer declarations.
      IMPLICIT DOUBLE PRECISION(a-h, o-z)
      IMPLICIT INTEGER(i-n)
      INTEGER pyk,pychge,pycomp
C...Commonblocks.
      common/pyjets/n,npad,k(4000,5),p(4000,5),v(4000,5)
      common/pydat1/mstu(200),paru(200),mstj(200),parj(200)
      common/pydat2/kchg(500,4),pmas(500,4),parf(2000),vckm(4,4)
      SAVE /pyjets/,/pydat1/,/pydat2/
C...Local array.
      dimension ijoin(*)
 
C...Check that partons are of right types to be connected.
      IF(njoin.LT.2) goto 120
      kqsum=0
      DO 100 ijn=1,njoin
        i=ijoin(ijn)
        IF(i.LE.0.OR.i.GT.n) goto 120
        IF(k(i,1).LT.1.OR.k(i,1).GT.3) goto 120
        kc=pycomp(k(i,2))
        IF(kc.EQ.0) goto 120
        kq=kchg(kc,2)*isign(1,k(i,2))
        IF(kq.EQ.0) goto 120
        IF(ijn.NE.1.AND.ijn.NE.njoin.AND.kq.NE.2) goto 120
        IF(kq.NE.2) kqsum=kqsum+kq
        IF(ijn.EQ.1) kqs=kq
  100 CONTINUE
      IF(kqsum.NE.0) goto 120
 
C...Connect the partons sequentially (closing for gluon loop).
      kcs=(9-kqs)/2
      IF(kqs.EQ.2) kcs=int(4.5d0+pyr(0))
      DO 110 ijn=1,njoin
        i=ijoin(ijn)
        k(i,1)=3
        IF(ijn.NE.1) ip=ijoin(ijn-1)
        IF(ijn.EQ.1) ip=ijoin(njoin)
        IF(ijn.NE.njoin) in=ijoin(ijn+1)
        IF(ijn.EQ.njoin) in=ijoin(1)
        k(i,kcs)=mstu(5)*in
        k(i,9-kcs)=mstu(5)*ip
        IF(ijn.EQ.1.AND.kqs.NE.2) k(i,9-kcs)=0
        IF(ijn.EQ.njoin.AND.kqs.NE.2) k(i,kcs)=0
  110 CONTINUE
 
C...Error exit: no action taken.
      RETURN
  120 CALL pyerrm(12,
     &'(PYJOIN:) given entries can not be joined by one string')
 
      RETURN
      END