pypdpr.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file pypdpr.f

 
C*********************************************************************
 
C...PYPDPR
C...Gives proton parton distributions according to a few different
C...parametrizations.
 
      SUBROUTINE pypdpr(X,Q2,XPPR)
 
C...Double precision and integer declarations.
      IMPLICIT DOUBLE PRECISION(a-h, o-z)
      IMPLICIT INTEGER(i-n)
      INTEGER pyk,pychge,pycomp
C...Commonblocks.
      common/pydat1/mstu(200),paru(200),mstj(200),parj(200)
      common/pydat2/kchg(500,4),pmas(500,4),parf(2000),vckm(4,4)
      common/pypars/mstp(200),parp(200),msti(200),pari(200)
      common/pyint1/mint(400),vint(400)
      SAVE /pydat1/,/pydat2/,/pypars/,/pyint1/
C...Arrays and data.
      dimension xppr(-6:6),q2min(16)
      DATA q2min/ 2.56d0, 2.56d0, 2.56d0, 0.4d0, 0.4d0, 0.4d0,
     &1.0d0, 1.0d0, 2*0d0, 0.25d0, 5d0, 5d0, 4d0, 4d0, 0d0/
 
C...Reset output array.
      DO 100 kfl=-6,6
        xppr(kfl)=0d0
  100 CONTINUE
 
C...Common preliminaries.
      nset=max(1,min(16,mstp(51)))
      IF(nset.EQ.9.OR.nset.EQ.10) nset=6
      vint(231)=q2min(nset)
      IF(mstp(57).EQ.0) THEN
        q2l=q2min(nset)
      ELSE
        q2l=max(q2min(nset),q2)
      ENDIF
 
      IF(nset.GE.1.AND.nset.LE.3) THEN
C...Interface to the CTEQ 3 parton distributions.
        qrt=sqrt(max(1d0,q2l))
 
C...Loop over flavours.
        DO 110 i=-6,6
          IF(i.LE.0) THEN
            xppr(i)=pycteq(nset,i,x,qrt)
          ELSEIF(i.LE.2) THEN
            xppr(i)=pycteq(nset,i,x,qrt)+xppr(-i)
          ELSE
            xppr(i)=xppr(-i)
          ENDIF
  110   CONTINUE
 
      ELSEIF(nset.GE.4.AND.nset.LE.6) THEN
C...Interface to the GRV 94 distributions.
        IF(nset.EQ.4) THEN
          CALL pygrvl(x, q2l, uv, dv, del, udb, sb, chm, bot, gl)
        ELSEIF(nset.EQ.5) THEN
          CALL pygrvm(x, q2l, uv, dv, del, udb, sb, chm, bot, gl)
        ELSE
          CALL pygrvd(x, q2l, uv, dv, del, udb, sb, chm, bot, gl)
        ENDIF
 
C...Put into output array.
        xppr(0)=gl
        xppr(-1)=0.5d0*(udb+del)
        xppr(-2)=0.5d0*(udb-del)
        xppr(-3)=sb
        xppr(-4)=chm
        xppr(-5)=bot
        xppr(1)=dv+xppr(-1)
        xppr(2)=uv+xppr(-2)
        xppr(3)=sb
        xppr(4)=chm
        xppr(5)=bot
 
      ELSEIF(nset.EQ.7) THEN
C...Interface to the CTEQ 5L parton distributions.
C...Range of validity 10^-6 < x < 1, 1 < Q < 10^4 extended by
C...freezing x*f(x,Q2) at borders.
        qrt=sqrt(max(1d0,min(1d8,q2l)))
        xin=max(1d-6,min(1d0,x))
 
C...Loop over flavours (with u <-> d notation mismatch).
        sumudb=pyct5l(-1,xin,qrt)
        ratudb=pyct5l(-2,xin,qrt)
        DO 120 i=-5,2
          IF(i.EQ.1) THEN
            xppr(i)=xin*pyct5l(2,xin,qrt)
          ELSEIF(i.EQ.2) THEN
            xppr(i)=xin*pyct5l(1,xin,qrt)
          ELSEIF(i.EQ.-1) THEN
            xppr(i)=xin*sumudb*ratudb/(1d0+ratudb)
          ELSEIF(i.EQ.-2) THEN
            xppr(i)=xin*sumudb/(1d0+ratudb)
          ELSE
            xppr(i)=xin*pyct5l(i,xin,qrt)
            IF(i.LT.0) xppr(-i)=xppr(i)
          ENDIF
  120   CONTINUE
 
      ELSEIF(nset.EQ.8) THEN
C...Interface to the CTEQ 5M1 parton distributions.
        qrt=sqrt(max(1d0,min(1d8,q2l)))
        xin=max(1d-6,min(1d0,x))
 
C...Loop over flavours (with u <-> d notation mismatch).
        sumudb=pyct5m(-1,xin,qrt)
        ratudb=pyct5m(-2,xin,qrt)
        DO 130 i=-5,2
          IF(i.EQ.1) THEN
            xppr(i)=xin*pyct5m(2,xin,qrt)
          ELSEIF(i.EQ.2) THEN
            xppr(i)=xin*pyct5m(1,xin,qrt)
          ELSEIF(i.EQ.-1) THEN
            xppr(i)=xin*sumudb*ratudb/(1d0+ratudb)
          ELSEIF(i.EQ.-2) THEN
            xppr(i)=xin*sumudb/(1d0+ratudb)
          ELSE
            xppr(i)=xin*pyct5m(i,xin,qrt)
            IF(i.LT.0) xppr(-i)=xppr(i)
          ENDIF
  130   CONTINUE
 
      ELSEIF(nset.GE.11.AND.nset.LE.15) THEN
C...GRV92LO, EHLQ1, EHLQ2, DO1 AND DO2 distributions:
C...obsolete but offers backwards compatibility.
        CALL pypdpo(x,q2l,xppr)
 
C...Symmetric choice for debugging only
      ELSEIF(nset.EQ.16) THEN
        xppr(0)=.5d0/x
        xppr(1)=.05d0/x
        xppr(2)=.05d0/x
        xppr(3)=.05d0/x
        xppr(4)=.05d0/x
        xppr(5)=.05d0/x
        xppr(-1)=.05d0/x
        xppr(-2)=.05d0/x
        xppr(-3)=.05d0/x
        xppr(-4)=.05d0/x
        xppr(-5)=.05d0/x
 
      ENDIF
 
      RETURN
      END