pynmes.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file pynmes.f

 
C*********************************************************************
 
C...PYNMES
C...Generates number of popcorn mesons and stores some relevant
C...parameters.
 
      SUBROUTINE pynmes(KFDIQ)
 
C...Double precision and integer declarations.
      IMPLICIT DOUBLE PRECISION(a-h, o-z)
      IMPLICIT INTEGER(i-n)
      INTEGER pyk,pychge,pycomp
C...Commonblocks.
      common/pydat1/mstu(200),paru(200),mstj(200),parj(200)
      common/pydat2/kchg(500,4),pmas(500,4),parf(2000),vckm(4,4)
      SAVE /pydat1/,/pydat2/
 
      mstu(121)=0
      IF(mstj(12).LT.2) RETURN
 
C..Old version: Get 1 or 0 popcorn mesons
      IF(mstj(12).LT.5)THEN
         popwt=parf(131)
         IF(kfdiq.NE.0) THEN
            kfdiqa=iabs(kfdiq)
            kfa=mod(kfdiqa/1000,10)
            kfb=mod(kfdiqa/100,10)
            kfs=mod(kfdiqa,10)
            popwt=parf(132)
            IF(kfa.EQ.3) popwt=parf(133)
            IF(kfb.EQ.3) popwt=parf(134)
            IF(kfs.EQ.1) popwt=popwt*sqrt(parj(4))
         ENDIF
         mstu(121)=int(popwt/(1d0+popwt)+pyr(0))
         RETURN
      ENDIF
 
C..New version: Store popcorn- or rank 0 diquark parameters
      mstu(122)=170
      parf(193)=parj(8)
      parf(194)=parf(139)
      IF(kfdiq.NE.0) THEN
         mstu(122)=180
         parf(193)=parj(10)
         parf(194)=parf(140)
      ENDIF
      IF(parf(194).LT.1d-5.OR.parf(194).GT.1d0-1d-5) THEN
         IF(parf(194).GT.1d0-1d-5) CALL pyerrm(9,
     &        '(PYNMES:) Neglecting too large popcorn possibility')
         RETURN
      ENDIF
 
C..New version: Get number of popcorn mesons
  100 rtst=pyr(0)
      mstu(121)=-1
  110 mstu(121)=mstu(121)+1
      rtst=rtst/parf(194)
      IF(rtst.LT.1d0) goto 110
      IF(kfdiq.EQ.0.AND.pyr(0)*(2d0+parf(135)*parf(161)).GT.
     &     (2d0+parf(135)*parf(161)*parf(138)**mstu(121))) goto 100
      RETURN
      END