pyerrm.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file pyerrm.f

 
C*********************************************************************
 
C...PYERRM
C...Informs user of errors in program execution.
 
      SUBROUTINE pyerrm(MERR,CHMESS)
 
C...Double precision and integer declarations.
      IMPLICIT DOUBLE PRECISION(a-h, o-z)
      IMPLICIT INTEGER(i-n)
      INTEGER pyk,pychge,pycomp
C...Commonblocks.
      common/pyjets/n,npad,k(4000,5),p(4000,5),v(4000,5)
      common/pydat1/mstu(200),paru(200),mstj(200),parj(200)
      SAVE /pyjets/,/pydat1/
C...Local character variable.
      CHARACTER chmess*(*)
 
C...Write first few warnings, then be silent.
      IF(merr.LE.10) THEN
        mstu(27)=mstu(27)+1
        mstu(28)=merr
        IF(mstu(25).EQ.1.AND.mstu(27).LE.mstu(26)) WRITE(mstu(11),5000)
     &  merr,mstu(31),chmess
 
C...Write first few errors, then be silent or stop program.
      ELSEIF(merr.LE.20) THEN
        IF(mstu(29).EQ.0) mstu(23)=mstu(23)+1
        mstu(30)=mstu(30)+1
        mstu(24)=merr-10
        IF(mstu(21).GE.1.AND.mstu(23).LE.mstu(22)) WRITE(mstu(11),5100)
     &  merr-10,mstu(31),chmess
        IF(mstu(21).GE.2.AND.mstu(23).GT.mstu(22)) THEN
          WRITE(mstu(11),5100) merr-10,mstu(31),chmess
          WRITE(mstu(11),5200)
          IF(merr.NE.17) CALL pylist(2)
          CALL pystop(3)
        ENDIF
 
C...Stop program in case of irreparable error.
      ELSE
        WRITE(mstu(11),5300) merr-20,mstu(31),chmess
        CALL pystop(3)
      ENDIF
 
C...Formats for output.
 5000 FORMAT(/5x,'Advisory warning type',i2,' given after',i9,
     &' PYEXEC calls:'/5x,a)
 5100 FORMAT(/5x,'Error type',i2,' has occured after',i9,
     &' PYEXEC calls:'/5x,a)
 5200 FORMAT(5x,'Execution will be stopped after listing of last ',
     &'event!')
 5300 FORMAT(/5x,'Fatal error type',i2,' has occured after',i9,
     &' PYEXEC calls:'/5x,a/5x,'Execution will now be stopped!')
 
      RETURN
      END