pydcyk.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file pydcyk.f

 
 
C*********************************************************************
 
C...PYDCYK
C...Handles flavour production in the decay of unstable particles
C...and small string clusters.
 
      SUBROUTINE pydcyk(KFL1,KFL2,KFL3,KF)
 
C...Double precision and integer declarations.
      IMPLICIT DOUBLE PRECISION(a-h, o-z)
      IMPLICIT INTEGER(i-n)
      INTEGER pyk,pychge,pycomp
C...Commonblocks.
      common/pydat1/mstu(200),paru(200),mstj(200),parj(200)
      common/pydat2/kchg(500,4),pmas(500,4),parf(2000),vckm(4,4)
      SAVE /pydat1/,/pydat2/
 
 
C.. Call PYKFDI directly if no popcorn option is on
      IF(mstj(12).LT.2) THEN
         CALL pykfdi(kfl1,kfl2,kfl3,kf)
         mstu(124)=kfl3
         RETURN
      ENDIF
 
      kfl3=0
      kf=0
      IF(kfl1.EQ.0) RETURN
      kf1a=iabs(kfl1)
      kf2a=iabs(kfl2)
 
      nsto=130
      nmax=min(mstu(125),10)
 
C.. Identify rank 0 cluster qq
      irank=1
      IF(kf1a.GT.10.AND.kf1a.LT.10000) irank=0
 
      IF(kf2a.GT.0)THEN
C.. Join jets: Fails if store not empty
         IF(mstu(121).GT.0) THEN
            mstu(121)=0
            RETURN
         ENDIF
         CALL pykfdi(kfl1,kfl2,kfl3,kf)
      ELSEIF(kf1a.GT.10.AND.mstu(121).GT.0)THEN
C.. Pick popcorn meson from store, return same qq, decrease store
         kf=mstu(nsto+mstu(121))
         kfl3=-kfl1
         mstu(121)=mstu(121)-1
      ELSE
C.. Generate new flavour. Then done if no diquark is generated
  100    CALL pykfdi(kfl1,0,kfl3,kf)
         IF(mstu(121).EQ.-1) goto 100
         mstu(124)=kfl3
         IF(kf.EQ.0.OR.iabs(kfl3).LE.10) RETURN
 
C.. Simple case if no dynamical popcorn suppressions are considered
         IF(mstj(12).LT.4) THEN
            IF(mstu(121).EQ.0) RETURN
            nmes=1
            kfprev=-kfl3
            CALL pykfdi(kfprev,0,kfl3,kfm)
C.. Due to eta+eta' suppr., a qq->M+qq attempt might end as qq->B+q
            IF(iabs(kfl3).LE.10)THEN
               kfl3=-kfprev
               RETURN
            ENDIF
            goto 120
         ENDIF
 
C test output qq against fake Gamma, then return if no popcorn.
         gb=2d0
         IF(irank.NE.0)THEN
            CALL pyzdis(1,2103,5d0,z)
            gb=5d0*(1d0-z)/z
            IF(1d0-parf(192)**gb.LT.pyr(0)) THEN
               mstu(121)=0
               goto 100
            ENDIF
         ENDIF
         IF(mstu(121).EQ.0) RETURN
 
C..Set store size memory. Pick fake dynamical variables of qq.
         nmes=mstu(121)
         CALL pyptdi(1,px3,py3)
         x=1d0
         popm=0d0
         g=gb
         popg=gb
 
C.. Pick next popcorn meson, test with fake dynamical variables
  110    kfprev=-kfl3
         px1=-px3
         py1=-py3
         CALL pykfdi(kfprev,0,kfl3,kfm)
         IF(mstu(121).EQ.-1) goto 100
         CALL pyptdi(kfl3,px3,py3)
         pm=pymass(kfm)**2+(px1+px3)**2+(py1+py3)**2
         CALL pyzdis(kfprev,kfl3,pm,z)
         g=(1d0-z)*(g+pm/z)
         x=(1d0-z)*x
 
         ptst=1d0
         gtst=1d0
         rtst=pyr(0)
         IF(mstj(12).GT.4)THEN
            popmn=sqrt((1d0-x)*(g/x-gb))
            popm=popm+pmas(pycomp(kfm),1)-pmas(pycomp(kfm),3)
            ptst=exp((popm-popmn)*parf(193))
            popm=popmn
         ENDIF
         IF(irank.NE.0)THEN
            popgn=x*gb
            gtst=(1d0-parf(192)**popgn)/(1d0-parf(192)**popg)
            popg=popgn
         ENDIF
         IF(rtst.GT.ptst*gtst)THEN
            mstu(121)=0
            IF(rtst.GT.ptst) mstu(121)=-1
            goto 100
         ENDIF
 
C.. Store meson
  120    IF(nmes.LE.nmax) mstu(nsto+mstu(121)+1)=kfm
         IF(mstu(121).GT.0) goto 110
 
C.. Test accepted system size. If OK set global popcorn size variable.
         IF(nmes.GT.nmax)THEN
            kf=0
            kfl3=0
            RETURN
         ENDIF
         mstu(121)=nmes
      ENDIF
 
      RETURN
      END