pyupin.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file pyupin.f

 
C*********************************************************************
 
C...PYUPIN
C...Fills the HEPRUP commonblock with info on incoming beams and allowed
C...processes, and optionally stores that information on file.
 
      SUBROUTINE pyupin
 
C...Double precision and integer declarations.
      IMPLICIT DOUBLE PRECISION(a-h, o-z)
      IMPLICIT INTEGER(i-n)
 
C...Commonblocks.
      common/pyjets/n,npad,k(4000,5),p(4000,5),v(4000,5)
      common/pysubs/msel,mselpd,msub(500),kfin(2,-40:40),ckin(200)
      common/pypars/mstp(200),parp(200),msti(200),pari(200)
      common/pyint5/ngenpd,ngen(0:500,3),xsec(0:500,3)
      SAVE /pyjets/,/pysubs/,/pypars/,/pyint5/
 
C...User process initialization commonblock.
      INTEGER maxpup
      parameter(maxpup=100)
      INTEGER idbmup,pdfgup,pdfsup,idwtup,nprup,lprup
      DOUBLE PRECISION ebmup,xsecup,xerrup,xmaxup
      common/heprup/idbmup(2),ebmup(2),pdfgup(2),pdfsup(2),
     &idwtup,nprup,xsecup(maxpup),xerrup(maxpup),xmaxup(maxpup),
     &lprup(maxpup)
      SAVE /heprup/
 
C...Store info on incoming beams.
      idbmup(1)=k(1,2)
      idbmup(2)=k(2,2)
      ebmup(1)=p(1,4)
      ebmup(2)=p(2,4)
      pdfgup(1)=0
      pdfgup(2)=0
      pdfsup(1)=mstp(51)
      pdfsup(2)=mstp(51)
 
C...Event weighting strategy.
      idwtup=3
 
C...Info on individual processes.
      nprup=0
      DO 100 isub=1,500
        IF(msub(isub).EQ.1) THEN
          nprup=nprup+1
          xsecup(nprup)=1d9*xsec(isub,3)
          xerrup(nprup)=xsecup(nprup)/sqrt(max(1d0,dble(ngen(isub,3))))
          xmaxup(nprup)=1d0
          lprup(nprup)=isub
        ENDIF
  100 CONTINUE
 
C...Write info to file.
      IF(mstp(161).GT.0) THEN
        WRITE(mstp(161),5100) idbmup(1),idbmup(2),ebmup(1),ebmup(2),
     &  pdfgup(1),pdfgup(2),pdfsup(1),pdfsup(2),idwtup,nprup
        DO 110 ipr=1,nprup
          WRITE(mstp(161),5200) xsecup(ipr),xerrup(ipr),xmaxup(ipr),
     &    lprup(ipr)
  110   CONTINUE
      ENDIF
 
C...Formats for printout.
 5100 FORMAT(1p,2i8,2e14.6,6i6)
 5200 FORMAT(1p,3e14.6,i6)
 
      RETURN
      END