pymewt.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file pymewt.f

 
C*********************************************************************
 
C...PYMEWT
C...Calculates actual ME weight in some initial-state showers.
C...Inparameter MECOR: kind of hard scattering process
C...            IFLCB: flavour combination of branching,
C...                   1 for fermion -> fermion,
C...                   2 for gluon/photon -> fermion
C...                   3 for fermion -> gluon/photon,
C...                   4 for gluon -> gluon
C...            Q2:    Q2 value of shower branching
C...            Z:     Z value of branching
C...In+outparameter PHIBR: azimuthal angle of branching
C...Outparameter WTME: actual ME weight
 
      SUBROUTINE pymewt(MECOR,IFLCB,Q2,Z,PHIBR,WTME)
 
C...Double precision and integer declarations.
      IMPLICIT DOUBLE PRECISION(a-h, o-z)
      IMPLICIT INTEGER(i-n)
      INTEGER pyk,pychge,pycomp
C...Commonblocks.
      common/pyjets/n,npad,k(4000,5),p(4000,5),v(4000,5)
      common/pydat1/mstu(200),paru(200),mstj(200),parj(200)
      common/pypars/mstp(200),parp(200),msti(200),pari(200)
      common/pyint1/mint(400),vint(400)
      common/pyint2/iset(500),kfpr(500,2),coef(500,20),icol(40,4,2)
      SAVE /pyjets/,/pydat1/,/pypars/,/pyint1/,/pyint2/
 
C...Default output.
      wtme=1d0
 
C...Define kinematics of shower branching in Mandelstam variables.
      sqm=vint(44)
      sh=sqm/z
      th=-q2
      uh=q2-sqm*(1d0-z)/z
 
C...Matrix-element corrections for f + fbar -> s-channel vector boson.
      IF(mecor.EQ.1) THEN
        IF(iflcb.EQ.1) THEN
          wtme=(th**2+uh**2+2d0*sqm*sh)/(sh**2+sqm**2)
        ELSEIF(iflcb.EQ.2) THEN
          wtme=(sh**2+uh**2+2d0*sqm*th)/((sh-sqm)**2+sqm**2)
        ENDIF
 
C...Matrix-element corrections for g + g -> Higgs (h0, H0, A0).
      ELSEIF(mecor.EQ.2) THEN
        IF(iflcb.EQ.3) THEN
          wtme=(sh**2+uh**2)/(sh**2+(sh-sqm)**2)
        ELSEIF(iflcb.EQ.4) THEN
          wtme=0.5d0*(sh**4+uh**4+th**4+sqm**4)/(sh**2-sqm*(sh-sqm))**2
        ENDIF

C...Matrix-element corrections for q + qbar -> Higgs (h0)
      ELSEIF(mecor.EQ.3) THEN
        IF(iflcb.EQ.2) THEN
          wtme=(sh**2+th**2+2d0*(sqm-th)*(sqm-sh))/
     1      (sh**2+2d0*sqm*(sqm-sh))
        ENDIF
      ENDIF
 
      RETURN
      END